-- makes camino slide in from the side of the screen
-- run as a trigger in quicksilver or butler
-- works best with only one window
-- v0.02 by 31d1 @cutup.org
-- make sure access for assistive devices is enabled:
-- System Preferences -> Universal Access -> Enable access for assistive devices

-- set a homepage (for no-open-window kludge):
set home to "http://localhost/"

tell application "System Events"
	
	-- if Camino isn't open
	if (not (exists application process "Camino")) then
		activate application "Camino"
	else
		tell application "Camino" to set z to number of windows
        -- get the display size, if there's a problem, replace the following line with: set scr to <width of your display in pixels>
		set scr to word 3 of (do shell script "defaults read /Library/Preferences/com.apple.windowserver | grep -w Width") as number
		
		-- if there's no open window 
		-- i can't set position or get it to slide in without creating weird unselectable windows.
		if (z is 0) then
			tell application "Camino" to open url home
			activate application "Camino"
			
			-- slide out
		else if (visible of application process "Camino" is true) then
			set x to 0
			repeat until x < -scr
				set position of window 1 of application process "Camino" to {x, 23}
				set x to x - 64
			end repeat
			-- bring the window back, but invisible, so clicking on the dock works as expected
			set visible of application process "Camino" to false
			set position of window 1 of application process "Camino" to {0, 23}
			
			-- slide in		
		else
			set x to -scr
			set position of window 1 of application process "Camino" to {-scr, 23}
			set visible of application process "Camino" to true
			activate application "Camino"
			repeat while x < 0
				set x to x + 64
				set position of window 1 of application process "Camino" to {x, 23}
			end repeat
			
		end if
	end if
end tell